// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,j,target,counter;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
	reset_dialog();
	add_dialog_str(0, "The Eagle Warrior finally falls dead. Good thing there was only one.", 0);
	add_dialog_str(1, "You remove his ornate decorations, and after a few minutes trying to get them on you think that you might just pass for a native.", 0);
	add_dialog_choice(0, "OK");
	run_dialog(1);

	reset_dialog();
	add_dialog_str(0, "This could help you get into the temple with rather less bloodshed.", 0);
	add_dialog_str(1, "The rest of your soldiers would be able to join you at the temple later.", 0);
	if (get_flag(1, 4) < 5)
	{
		add_dialog_str(2, "You instruct your remaining troops to mop up any more natives nearby, and continue on towards the temple.", 0);
	}
	add_dialog_choice(0, "OK");
	run_dialog(1);
	change_spec_item(0,1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);

	counter = 0;

	if ((dist_to_party() <= 8) && (get_attitude(ME) >= 10) && (get_ran(3, 0, 1) == 0))
	{
		i = my_loc_x() - 1;
		j = my_loc_y() - 1;
		while (i < my_loc_x() + 2)
		{
			j = my_loc_y() - 1;
			while (j < my_loc_y() + 2)
			{
				if (get_terrain(i, j) >= 425 && get_terrain(i, j) <= 444)
				{
					set_terrain(i, j, 0);
					if (get_ran(1, 0, 1))
					{
						place_monster(i, j, 235, 1);
					}
					else
					{
						place_monster(i, j, 236, 1);
					}
					counter = counter + 1;
				}
				j = j + 1;
			}
			i = i + 1;
		}
		if (counter > 0)
		{
			print_named_str(ME, "calls an ambush!");
		}
	}
		
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;